README.md

Ballerina Constraint Library

The Ballerina constraint library provides annotations to add constraints to Ballerina types and an API to validate the values with respect to the constraints defined in the respective types.

Constraint annotations

This library provides the following annotations on Ballerina types to validate the values created with the respective types.

Annotation	Supported Constraints	Associated Ballerina Type(s)
@constraint:Int	minValue, maxValue, minValueExclusive, maxValueExclusive, maxDigits, maxIntegerDigits, maxFractionDigits	int
@constraint:Float	minValue, maxValue, minValueExclusive, maxValueExclusive, maxDigits, maxIntegerDigits, maxFractionDigits	float
@constraint:Number	minValue, maxValue, minValueExclusive, maxValueExclusive, maxDigits, maxIntegerDigits, maxFractionDigits	int, float, decimal
@constraint:String	length, minLength, maxLength, pattern	string
@constraint:Array	length, minLength, maxLength	any[]
@constraint:Date	option - PAST or FUTURE or PAST_OR_PRESENT or FUTURE_OR_PRESENT	constraint:Date

The following example demonstrates how to apply constraint annotations to types.

@constraint:String { pattern: re `^[a-zA-Z0-9._%+-]+@[a-zA-Z0-9.-]+\\.[a-zA-Z]{2,}$` }
public type Email string;

@constraint:Date { option: constraint:PAST }
public type DOB time:Date;

public type Person record {|
    @constraint:String { minLength: 5, maxLength: 10 }
    string name;
    @constraint:Int { minValue: 18, maxValue: 60 }
    int age;
    Email email;
    @constraint:Array { minLength: 1, maxLength: 5 }
    string[] phoneNumbers;
    DOB dob;
|};

Constraint validation

The validate function in this library can be used to validate the values with respect to the constraints defined in the respective types.

The following example demonstrates how to validate a value with respect to constraints in the type. The respective type is automatically inferred from the expression context.

public function main() returns error? {
    Person person = {
        name: "John",
        age: 25,
        email: "[email protected]",
        phoneNumbers: ["1234567890", "0987654321"],
        dob: { year: 1996, month: 5, day: 15 }
    };
    
    Person|error personValidated = constraint:validate(person);
    if personValidated is error {
        io:println("Validation failed: " + personValidated.message());
    } else {
        io:println("Validation successful");
    }
}

Custom error messages on validation failures

Optionally a custom error message can be provided for each constraint. The following example demonstrates how to provide custom error messages for constraints.

@constraint:String { 
    pattern: {
        value: re `^[a-zA-Z0-9._%+-]+@[a-zA-Z0-9.-]+\\.[a-zA-Z]{2,}$`,
        message: "Invalid email address"
    }
}
public type Email string;

@constraint:Date {
    option: {
        value: constraint:PAST,
        message: "Date of birth should be in the past"
    },
    message: "Invalid date found"
}
public type DOB time:Date;

public type Person record {|
    @constraint:String { 
        minLength: 5, 
        maxLength: {
            value: 10,
            message: "Name should be less than 10 characters"
        }
    }
    string name;
    @constraint:Int {
        minValue: {
            value: 18,
            message: "Age should be greater than 18"
        },
        maxValue: 60
    }
    int age;
    Email email;
    @constraint:Array { 
        minLength: {
            value: 1,
            message: "At least one phone number should be provided"
        },
        maxLength: 5 
    }
    string[] phoneNumbers;
    DOB dob;
|};

Issues and projects

Issues and Projects tabs are disabled for this repository as this is part of the Ballerina Standard Library. To report bugs, request new features, start new discussions, view project boards, etc., go to the Ballerina Standard Library parent repository.

This repository only contains the source code for the module.

Build from the source

Set up the prerequisites

1. Download and install Java SE Development Kit (JDK) version 17 (from one of the following locations).

   • Oracle

   • OpenJDK

     Note: Set the JAVA_HOME environment variable to the path name of the directory into which you installed JDK.

2. Export your GitHub Personal Access Token (PAT) with the read package permission as follows:

   export packageUser=<Username>
   export packagePAT=<Personal Access Token>
   

3. Download and install Docker.

Build the source

Execute the commands below to build from the source.

1. To build the package:

   ./gradlew clean build
   

2. To run the tests:

   ./gradlew clean test
   

3. To run a group of tests

   ./gradlew clean test -Pgroups=<test_group_names>
   

4. To build the without the tests:

   ./gradlew clean build -x test
   

5. To debug package implementation:

   ./gradlew clean build -Pdebug=<port>
   

6. To debug with Ballerina language:

   ./gradlew clean build -PbalJavaDebug=<port>
   

7. Publish the generated artifacts to the local Ballerina central repository:

   ./gradlew clean build -PpublishToLocalCentral=true
   

8. Publish the generated artifacts to the Ballerina central repository:

   ./gradlew clean build -PpublishToCentral=true
   

Contribute to Ballerina

As an open source project, Ballerina welcomes contributions from the community.

For more information, go to the contribution guidelines.

Code of conduct

All contributors are encouraged to read the Ballerina Code of Conduct.

Useful links

• For more information go to the constraint library.
• For example demonstrations of the usage, go to Ballerina By Examples.
• Chat live with us via our Discord server.
• Post all technical questions on Stack Overflow with the #ballerina tag.